##
# TCSH Expanded C-Shell INITIALIZATION FILE
#
# Wilfredo Sanchez Jr. | tritan@mit.edu
# July 09, 1992
#
# MIT Project Athena
#
# ORIGINAL SOURCES: /usr/athena/lib/init/cshrc (ATHENA REL 7.3P)
##

set default_initdir      = /usr/share/init
set default_tcsh_initdir = ${default_initdir}/tcsh
set user_initdir         = ~/Library/init
set user_tcsh_initdir    = ${user_initdir}/tcsh

if (-r $user_tcsh_initdir) then
  set initdir      = $user_initdir
  set tcsh_initdir = $user_tcsh_initdir
else
  set initdir      = $default_initdir
  set tcsh_initdir = $default_tcsh_initdir
endif

# SET UP HOST-DEPENDANT VARIABLES, ETC.

set path = (/bin /usr/bin /usr/dt/bin /usr/openwin/bin /usr/ucb		\
	    /usr/local/bin /usr/contrib/bin /opt/bin /opt/local/bin	\
	    /usr/etc /etc /sbin /usr/sbin /usr/ccs/bin )

setenv MANPATH "/usr/man:/usr/share/man:/usr/dt/man:/usr/openwin/man:/usr/ucb/man:/usr/local/man:/usr/local/share/man:/usr/contrib/man:/opt/man:/opt/share/man:/opt/local/man:/opt/local/share/man"

set host = `hostname`
set host = `echo $host | tr A-Z a-z`

set user=`whoami`

setenv HOST $host
setenv USER $user

# User ID (csh doesn't set this, tcsh does)
if (! $?uid) set uid = `id | cut -d = -f 2 | cut -d \( -f 1`

# MISCELLANEOUS SETS
if (! $?version) set version = "unknown"
unset autologout

# cd to ~ if not root
if ($uid) cd

# Temporary Directory
set tmpdir = /tmp/$user

# SET COMMAND SEARCH PATH AND MAN PATH
if (-r ${tcsh_initdir}/path) source ${tcsh_initdir}/path

# ENVIRONMENT SETUP

if ($?prompt) set interactive

if (! $?ENV_SET) then	# Top-most shell
  if (-r ${default_tcsh_initdir}/environment && ($?prompt || $?XSESSION)) then
    #echo "Initializing environment..."
    source ${default_tcsh_initdir}/environment
    setenv ENV_SET
  endif
else  			# NON ENV_SET, 2nd+ shells
  # noop
endif

if (-r ${default_tcsh_initdir}/tcsh.defaults) then
    source ${default_tcsh_initdir}/tcsh.defaults
endif

# DEFAULT LOGIN SOURCES
if (-r ${tcsh_initdir}/rc.mine) source ${tcsh_initdir}/rc.mine

if ($?interactive) then
  # These aren't useful for non-interactive sessions
  if (-r ${default_tcsh_initdir}/aliases && ! $?noalias) then
    source ${default_tcsh_initdir}/aliases
  endif
  if (-r ${default_tcsh_initdir}/completions && ! $?noalias && $?version) then
    if ("$version" =~ tcsh*) source ${default_tcsh_initdir}/completions
  endif
endif
