##
# TCSH Expanded C-Shell INITIALIZATION FILE
# Aliases file
#
# Wilfredo Sanchez Jr. | tritan@mit.edu
# June 10, 1994
#
# MIT Project Athena
##
alias .		'pwd'
alias ..	'cd ..'
alias c		'clear'
alias cd..	'cd ..'
alias cdwd	'cd `pwd`'
alias clobber	'unset noclobber'
alias cp	'echo \!* ; \cp -i \!*'		# Prevent overwrite
alias cwd	'echo $cwd'
alias files	'find \!:1 -type f -print'
alias ff	'find . -name \!:1 -print'
alias h		'history'
alias j		'jobs -l'
alias kj	'kill %\!:1'			# kj n => Kill Job n
alias l 	'ls -lg'
alias la	'ls -A'
alias lf	'ls-F'
alias line	sed -n \'\!:1 p\' \!:2	# line 5 file => show line 5 of file
alias ll	'ls -lag \!* | m'
alias m		'more'
alias md	'mkdir'
alias mv	'echo \!* ; \mv -i \!*'		# Prevent overwrite
alias noclobber 'set noclobber'
alias po	'popd'
alias pu	'pushd'
alias rd	'rmdir'
alias rm 	'echo \!* ; \rm -i \!*'		# Prevent accidents
alias term 	'set noglob; unsetenv TERMCAP; eval `tset -s -I -Q - \!*`'
alias word	'grep \!* /usr/dict/web2'	# Grep thru dictionary
alias wordcount	'(cat \!* | tr -s '\'' 	.,;:?\!()[]"'\'' '\''\012'\'' |' \
		'cat -n | tail -1 | awk '\''{print $1}'\'')' # Histogram words

##
# Read user's aliases
##
if (-r ${tcsh_initdir}/aliases.mine) then
  source ${tcsh_initdir}/aliases.mine
endif

